From a493beec6f1f2d0df6296c16d0333f6440ee5f55 Mon Sep 17 00:00:00 2001
From: Ground-Zerro <161684825+Ground-Zerro@users.noreply.github.com>
Date: Sat, 1 Nov 2025 21:29:55 +1100
Subject: [PATCH] Add files via upload

---
 Windows/Win.bat | 112 ++++++++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 112 insertions(+)
 create mode 100644 Windows/Win.bat

diff --git a/Windows/Win.bat b/Windows/Win.bat
new file mode 100644
index 0000000..cdb518a
--- /dev/null
+++ b/Windows/Win.bat
@@ -0,0 +1,112 @@
+@echo off
+setlocal enabledelayedexpansion
+chcp 65001 > NUL
+
+REM Проверка Python 3
+:CheckPython
+python --version 2>NUL | findstr /I "Python 3" >NUL
+if ERRORLEVEL 1 (
+    echo Python 3 не установлен.
+    choice /C YN /M "Установить?"
+    if ERRORLEVEL 2 (
+        echo Без Python 3 ничего не получится...
+        pause
+        exit /b 1
+    ) else (
+        call :InstallPython
+    )
+) else (
+    echo Python 3 установлен.
+)
+goto :CheckModules
+
+REM Инсталляция Python 3
+:InstallPython
+echo Загрузка дистрибутива...
+powershell -Command "if ($PSVersionTable.PSVersion.Major -ge 3) {Invoke-WebRequest -Uri 'https://www.python.org/ftp/python/3.12.5/python-3.12.5-amd64.exe' -OutFile 'python_installer.exe'} else {Start-BitsTransfer -Source 'https://www.python.org/ftp/python/3.12.5/python-3.12.5-amd64.exe' -Destination 'python_installer.exe'}"
+
+REM Проверяем успешность загрузки
+if not exist "python_installer.exe" (
+    echo Ошибка загрузки установщика Python 3.
+    pause
+    exit /b 1
+)
+
+REM Установка Python 3
+echo Установка...
+echo PS - не забудьте ее разрешить в соседнем окне
+python_installer.exe /quiet InstallAllUsers=1 PrependPath=1
+del /q /f python_installer.exe
+
+REM Оповещение о перезапуске
+echo.
+echo Установка завершена, но требуется обновить окружение.
+echo - закройте это окно и запустите скрипт снова.
+pause
+exit /b 0
+
+REM Проверка и установка необходимых модулей Python
+:CheckModules
+set "modules=dnspython httpx colorama tqdm"
+echo.
+echo Проверка необходимых библиотек...
+
+for %%m in (%modules%) do (
+    pip show %%m >NUL 2>&1
+    if ERRORLEVEL 1 (
+        echo Установка библиотеки %%m...
+        pip install %%m
+        if ERRORLEVEL 1 (
+            echo Не удалось установить библиотеку %%m. Проверьте pip.
+            exit /b 1
+        )
+    )
+)
+
+goto :DownloadMain
+
+REM Загрузка и запуск main.py
+:DownloadMain
+echo Загрузка Domain Mapper...
+powershell -Command "if ($PSVersionTable.PSVersion.Major -ge 3) {Invoke-WebRequest -Uri 'https://raw.githubusercontent.com/Ground-Zerro/DomainMapper/main/main.py' -OutFile 'main.py'} else {Start-BitsTransfer -Source 'https://raw.githubusercontent.com/Ground-Zerro/DomainMapper/main/main.py' -Destination 'main.py'}"
+
+if not exist "main.py" (
+    echo Ошибка загрузки Domain Mapper.
+    pause
+    exit /b 1
+)
+
+cls
+REM Запуск main.py
+echo Запускаем...
+python main.py
+if ERRORLEVEL 1 (
+    echo Ошибка выполнения main.py.
+    pause
+    del /q /f main.py
+    exit /b 1
+)
+
+echo Копирование файлов на рабочий стол...
+
+if exist domain-ip-resolve.txt (
+    move /y domain-ip-resolve.txt %UserProfile%\Desktop\domain-ip-resolve.txt
+    echo Файл скопирован в %UserProfile%\Desktop\domain-ip-resolve.txt
+) else (
+    echo Поиск разделенных файлов...
+    set "found=0"
+    for %%f in (domain-ip-resolve_p*.txt) do (
+        move /y "%%f" "%UserProfile%\Desktop\%%f"
+        echo Файл %%f скопирован на рабочий стол
+        set "found=1"
+    )
+    if "!found!"=="0" (
+        echo Не найдено файлов для копирования.
+    )
+)
+
+echo Программа завершена.
+del /q /f main.py
+endlocal
+pause
+exit /b 0